본문 바로가기
Home Board 배치파일 Batch
?

단축키

Prev이전 문서

Next다음 문서

크게 작게 위로 아래로 댓글로 가기 인쇄
배치파일
2019.09.01 12:00

CASZONE X-TOOLS v4.8.2

관리자
조회 수 2587
Atachment
첨부 '2'

x-tools.PNG

 

IP 대역 98.18 부분을 사용 할 사내망 IP 대역으로 변경하세요.

 

RAM---Computer IP Setting 안에

SUBNETMASK, DNS1, DNS2 사내망 네트워크 정보로 수정하여 사용하세요.

 

 

@echo off

title CASZONE X-TOOLS v4.8 (개발자:김인철)

>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

if '%errorlevel%' NEQ '0' (

    echo Run as Administrator...

    goto UACPrompt

) else ( goto gotAdmin )

:UACPrompt

    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"

    set params = %*:"=""

    echo UAC.ShellExecute "cmd.exe", "/c %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"

    rem del "%temp%\getadmin.vbs"

    exit /B

:gotAdmin

 

 

:MENU

 

c:

cd\

cls

echo.

echo ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒

echo.

echo          CASZONE X-TOOLS v4.8 (개발자:김인철)

echo.

echo ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒

echo.

echo.

echo [1] 교체 전 - 기존 PC 에서 (백업)

echo.

echo.

echo [2] 교체 후 - 새 PC 에서 (복원)

echo.

echo.

echo [3] 컴퓨터 이름 및 네트워크 ip 변경

echo.

echo [4] 프로그램 닫기

echo.

echo.

set /p choice= "진행 할 작업 번호를 입력하세요 : "

echo. 

if "%choice%" == "1" goto :BEFORE

if "%choice%" == "2" goto :AFTER

if "%choice%" == "3" goto :NETWORKYESPLUS

if "%choice%" == "4" goto :END

goto MENU

echo.

 

 

:BEFORE

 

cls

 

:DRVCHECK

echo.

md "D:\###CASZONE###"

echo.

if %errorlevel% equ 0 (

    echo.

    echo D 드라이브에 폴더를 생성 하였습니다.

    goto DRVCHECK-D

) else (

    echo.

    echo D 드라이브로 설정 할 수 없습니다.

    goto DRVCHECK-E

) 

exit /b

 

 

:DRVCHECK-D

set DISK=D

goto BEFORE-SET

 

:DRVCHECK-E

echo.

echo.

echo 네트워크 정보 및 인증서를 백업 할 위치 선택하세요.

echo.

echo C 파티션을 제외한 드라이브를 지정하세요. 없으면 관리자에게 문의.

echo.

set /p DISK="알파벳 d 또는 e 식으로 입력하세요. : "  

echo.

echo.

echo 위에 선택한 경로를 재확인합니다. 맞은면 엔터! 

echo ──────────────────────── 

goto BEFORE-SET

 

 

:BEFORE-SET

 

set folder="%DISK%:\###CASZONE###"

 

set file="%folder%\_PRINTER_INFO.txt"

 

echo.

echo %folder%

echo.

echo ──────────────────────── 

echo.

 

pause

 

md "%folder%"

 

echo ───────────────────────── 

echo 1 PC 교체 전 - 기존 PC 설정 값 확인

echo ───────────────────────── 

echo. 

echo 1-1 컴퓨터 이름, 윈도우 계정명 확인 

echo. 

 

wmic computersystem get "Name", "UserName"

wmic computersystem get "Name", "UserName" > %file%

 

echo. 

echo 1-2 기존 PC본체 시리얼넘버 확인

echo. 

 

wmic computersystem get "Model","Manufacturer"

wmic bios get serialnumber

wmic computersystem get "Model","Manufacturer" >> %file%

wmic bios get serialnumber >> %file%

 

echo. 

echo ───────────────────────── 

echo 2 프린터 IP 및 포트 정보, 공유 설정 확인 

echo ───────────────────────── 

 

wmic printer get "Name", "PortName", "ShareName"

wmic printer get "Name", "PortName", "ShareName" >> %file%

 

echo.

echo.

echo ─────────────────────────

echo 3 네트워크 IP (이더넷) 정보 확인

echo ─────────────────────────

echo.

for /f "tokens=1-2 delims=:" %%a in ('ipconfig^|find "IPv4"') do set ip=%%b

set ip=%ip:~1%

echo IP address : %ip%

ipconfig /all > "%folder%\%ip%.txt"

 

echo.

echo.

echo.

echo ─────────────────────────

echo 4 기존 사용자 공인인증서 백업 작업

echo ─────────────────────────

echo.

echo.

echo.

 

echo 공인인증서 백업 대상 폴더 생성

md "%folder%\GPKI"

md "%folder%\NPKI_program\NPKI"

md "%folder%\NPKI_appdata\NPKI"

md "%folder%\Profiles\Favorites"

 

md "%folder%\Profiles\Sticky Notes"

md "%folder%\Profiles\SMYSoft"

md "%folder%\Profiles\Memoit"

md "%folder%\Profiles\DesktopCal"

 

xcopy "%systemdrive%\GPKI" "%folder%\GPKI" /e /h /k /y

xcopy "%programfiles%\NPKI" "%folder%\NPKI_program\NPKI" /e /h /k /y

xcopy "%userprofile%\AppData\LocalLow\NPKI" "%folder%\NPKI_appdata\NPKI" /e /h /k /y

xcopy "%userprofile%\Favorites" "%folder%\Profiles\Favorites" /e /h /k /y

 

xcopy "%userprofile%\AppData\Roaming\Microsoft\Sticky Notes" "%folder%\Profiles\Sticky Notes" /e /h /k /y

xcopy "C:\SMYSoft" "%folder%\Profiles\SMYSoft" /e /h /k /y

xcopy "%userprofile%\AppData\Local\Memoit" "%folder%\Profiles\Memoit" /e /h /k /y

xcopy "%userprofile%\AppData\Roaming\DesktopCal" "%folder%\Profiles\DesktopCal" /e /h /k /y

 

:: E 비어 있는 경우를 포함하여 디렉터리와 하위 디렉터리를 복사합니다.

:: H 숨겨진 파일과 시스템 파일도 복사합니다.

:: K 특성을 복사합니다. 일반적인 Xcopy는 읽기 전용 특성을 다시 설정합니다.

:: Y 기존 대상 파일을 덮어쓸지 여부를 묻지 않습니다.

 

md "%folder%\%DATE%\GPKI"

md "%folder%\%DATE%\NPKI_program\NPKI"

md "%folder%\%DATE%\NPKI_appdata\NPKI"

 

robocopy /MIR /ZB /XO /XA:H /R:1 /W:1 /V /NJH /NJS /TEE "%systemdrive%\GPKI" "%folder%\%DATE%\GPKI"

robocopy /MIR /ZB /XO /XA:H /R:1 /W:1 /V /NJH /NJS /TEE "%programfiles%\NPKI" "%folder%\%DATE%\NPKI_program\NPKI"

robocopy /MIR /ZB /XO /XA:H /R:1 /W:1 /V /NJH /NJS /TEE "%userprofile%\AppData\LocalLow\NPKI" "%folder%\%DATE%\NPKI_appdata\NPKI"

 

echo.

echo.

 

copy /y "%~dp0\*CASZONE*.cmd" "%folder%"

 

pause

 

%SystemRoot%\explorer.exe /n, /e, "%folder%"

 

goto END

 

 

echo ========================================================================

 

 

:AFTER

 

c:

cd\

cls

 

echo.

echo.

echo ─────────────────────────

echo 1 사용자 인증서 복원

echo ─────────────────────────

echo.

cd\

cd %~dp0

 

if exist "%~dp0\GPKI" (

echo.

echo 인증서를 복원합니다.

echo.

echo ──────────────────────── 

echo.

echo %~dp0

echo.

echo %~dp0\GPKI

echo.

echo %~dp0\NPKI_program\NPKI

echo.

echo %~dp0\NPKI_appdata\NPKI

echo.

echo ──────────────────────── 

echo.

pause

echo.

  goto AFTERYES

  ) else (

echo.

echo 인증서 GPKI 와 NPKI_appdata 폴더가 없습니다.

echo.

pause

echo.

  goto AFTERQA

  )

if end

 

 

 

:AFTERQA

cls

echo.

echo.

echo.

SET /p qa="백업 된 인증서가 %~dp0 폴더에 있나요? (Y/N) : "

if /i %qa%==y goto AFTERYES

if /i %qa%==n goto AFTER

goto AFTER

echo.

 

 

 

:AFTERYES

 

cls

 

md "%systemdrive%\GPKI"

md "%programfiles%\NPKI"

md "%userprofile%\AppData\LocalLow\NPKI"

 

xcopy "%~dp0\GPKI" "%systemdrive%\GPKI" /e /h /k /y

xcopy "%~dp0\NPKI_program\NPKI" "%programfiles%\NPKI" /e /h /k /y

xcopy "%~dp0\NPKI_appdata\NPKI" "%userprofile%\AppData\LocalLow\NPKI" /e /h /k /y

xcopy "%~dp0\Profiles\Favorites" "%userprofile%\Favorites" /e /h /k /y

 

echo.

echo 인증서 복사가 완료 되었습니다.

echo.

pause

echo.

goto NETWORK

 

 

:NETWORK

 

cls

 

echo.

echo.

echo ─────────────────────────

echo 2 새로운 PC 컴퓨터 정보 및 네트워크 IP 변경

echo ─────────────────────────

echo.

echo.

if exist "%~dp0\98.18.*.txt" (

echo.

echo 네트워크 IP 텍스트 정보가 확인 되었습니다.

echo.

pause

echo.

  goto NETWORKYES

  ) else (

echo.

echo 네트워크 IP 텍스트 파일이 없습니다.

echo.

pause

echo.

  goto NETWORKQA

  )

if end

 

 

 

:NETWORKQA

 

SET /p netqa="네트워크 IP 텍스트 파일이 %~dp0 폴더에 있나요? (Y/N) : "

if /i %netqa%==y goto NETWORKYES

if /i %netqa%==n goto AFTER

goto AFTER

echo.

 

 

 

:NETWORKYES

cls

 

FOR /F "delims=" %%i IN ("%~dp0\98.18.*.txt") DO (SET filename=%%~ni)

ECHO %filename%

ECHO %filename:~0,5%

 

for /F "tokens=3,4 delims=. " %%a in ("%filename%") do (

   set ipC=%%a

   set ipD=%%b

)

echo %filename:~0,5%.%ipC%.%ipD%

echo.

goto StartConfig

 

 

 

:NETWORKYESPLUS

 

del /f /q "%TEMP%\98*.txt"

cls

echo.

echo.

set ipAB=98.18.

set /p ipCD="나머지 아이피를 입력하세요 : 98.18."

echo "%ipAB%%ipCD%" >> "%TEMP%\%ipAB%%ipCD%.txt"

 

FOR /F "delims=" %%i IN ("%TEMP%\98*.txt") DO (SET filename=%%~ni)

ECHO %filename%

ECHO %filename:~0,5%

 

for /F "tokens=3,4 delims=. " %%a in ("%filename%") do (

   set ipC=%%a

   set ipD=%%b

)

echo %filename:~0,5%.%ipC%.%ipD%

echo.

goto StartConfig

 

 

:StartConfig

cls

 

REM ------------------------------------- Computer IP Setting -----------------------------------------------

 

SET IPx4=%filename%

 

SET SUBNETMASK=255.255.255.128

SET GATEWAY=%filename:~0,5%.%ipC%.1

SET DNS1=10.1.1.5

SET DNS2=168.126.63.1

 

REM ---------------------------------------------------------------------------------------------------------

 

:NICNameSetting

 

echo.

ECHO 등록 할 네트워크 IP : %IPx4%

ECHO 등록 할 네트워크 GATEWAY : %GATEWAY%

echo.

echo 어댑터 리스트입니다. 연결 된 어댑터를 확인하세요.  

echo ───────────────────────────────────

wmic nic where PhysicalAdapter=TRUE get NetConnectionID,ProductName

echo ───────────────────────────────────

echo.

echo 1 : 이더넷  (윈도우10 네트워트 어댑터)

echo.

echo 2 : 로컬 영역 연결  (윈도우7 네트워트 어댑터)

echo.

echo 3 : 수동으로 입력하기

echo.

echo.

SET /p NICchoice="네트워크 어댑터 선택하세요. (숫자 입력)  : "

echo.

if /i %NICchoice%==1 goto Ethernet

if /i %NICchoice%==2 goto LocalNetwork

if /i %NICchoice%==3 goto NetworkNameChange

goto NICNameSetting

echo.

echo.

 

:Ethernet

SET NICName=이더넷

goto COMNameSetting

 

:LocalNetwork

SET NICName=로컬 영역 연결

goto COMNameSetting

 

 

:NetworkNameChange

cls

echo.

FOR /F "delims=" %%i IN ('wmic nic where "PhysicalAdapter=TRUE" get NetConnectionID') DO echo [네트워크 어댑터] %%i

echo.

SET /p NICName="네트워크 어댑터 확인 후 텍스트를 그대로 입력하세요. : "

echo.

goto COMNameSetting

 

 

:COMNameSetting

echo.

echo.

SET /p COMName="사용자 이름을 입력하세요 (컴퓨터 이름) : "

echo.

echo.

SET /p WorkGroup="부서(과)명을 입력하세요 (작업 그룹) : "

echo.

echo.

cls

 

echo.

echo.

ECHO 전체 컴퓨터 이름  : %COMName%

echo.

ECHO 작업 그룹  : %WorkGroup%

echo.

ECHO 네트워크   : %NICName%

echo.

ECHO IP    : %IPx4%

echo.

ECHO SUBNETMASTK   : %SUBNETMASK%

echo.

ECHO GATEWAY   : %GATEWAY%

echo.

ECHO DNS1    : %DNS1%

echo.

ECHO DNS2    : %DNS2%

echo.

echo.

goto QA

echo.

 

:QA

echo.

echo.

SET /p qa="설정 할 네트워크 값이 정확합니까? (1.예 / 2.아니요) 숫자 입력 : "

if /i %qa%==1 goto Exec

if /i %qa%==2 goto NETWORK

goto QA

echo.

echo.

 

 

:Exec

echo.

ECHO Starting Config....

echo.

ECHO y|REG add HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters /v Hostname /t REG_SZ /d %COMName% > nul

ECHO y|REG add HKLM\SYSTEM\CurrentControlSet\Services\Tcpip\Parameters /v "NV Hostname" /t REG_SZ /d %COMName% > nul

ECHO y|REG add HKLM\SYSTEM\CurrentControlSet\Control\ComputerName\ComputerName /v ComputerName /t REG_SZ /d %COMName% > nul

echo.

echo.

echo.

ECHO 네트워크 IP 값 설정합니다.

echo.

netsh interface ip set address "%NICName%" static %IPx4% %SUBNETMASK% %GATEWAY% 1

echo.

ECHO 네트워크 DNS1 값 설정합니다.

echo.

netsh interface ip set dns name="%NICName%" source=static addr=%DNS1% register=PRIMARY

echo.

ECHO 네트워크 DNS2 값 설정합니다.

echo.

netsh interface ip add dns name="%NICName%" addr=%DNS2% index=2

echo.

echo.

wmic computersystem where name="%computername%" call joindomainorworkgroup name="%WorkGroup%"

echo.

echo 컴퓨터 이름이 %COMName% 으로 변경되었습니다.

echo.

echo 작업 그룹명을 %WorkGroup% 으로 변경되었습니다. 

echo.

sysdm.cpl

echo.

echo.

echo 네트워크 정보를 확인하세요.

echo.

ncpa.cpl

echo.

pause

 

goto END

echo.

 

:END

exit

 

 

 

<코드 수정 시, 참고 동영상>

 

영상보기 : https://youtu.be/napQNu5vSBg

 

 

#금천블루베리 #소프트엑스

 

 

위로 아래로 댓글로 가기 인쇄
  1. No Image notice

    CASZONE X-TOOLS Add-On v1.6.3

    @echo off mode con:cols=65 lines=20 title CASZONE X-TOOLS Add-On v1.6.3 (개발자:김인철) >nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system" if '%errorlevel%' NEQ '0' ( echo Run as Administrat...
    Date2019.09.18 Category배치파일 Views3101
    read more
  2. notice

    CASZONE X-TOOLS v4.8.2

    IP 대역 98.18 부분을 사용 할 사내망 IP 대역으로 변경하세요. RAM---Computer IP Setting 안에 SUBNETMASK, DNS1, DNS2 사내망 네트워크 정보로 수정하여 사용하세요. @echo off title CASZONE X-TOOLS v4.8 (개발자:김인철) >nul 2>&1 "%SYSTEMROOT%\s...
    Date2019.09.01 Category배치파일 Views2587
    read more
  3. No Image

    Auto_Setup_OFFICE2013_B

    @echo off cd\ net use b: /d /y net use b: "\\172.24.93.71\_jw\Setup_\MS_Office_Professional_Plus_2013" /user:user chlrhkdals cls echo. echo. echo. echo. b: Setup.exe set /p choice= 프로그램 설치가 완료 되었습니까? 예(Y) / 아니오(N) : if "%ch...
    Date2016.11.22 Views317
    Read More
  4. No Image

    Auto_Setup_OFFICE2013

    @echo off cd\ net use x: /d /y net use x: "\\172.24.93.71\_jw\Setup_\MS_Office_Professional_Plus_2013" /user:user chlrhkdals cls echo. echo. echo. x: Setup.exe set /p choice= 프로그램 설치가 완료 되었습니까? 예(Y) / 아니오(N) : if "%choice%"...
    Date2016.11.22 Views353
    Read More
  5. No Image

    Auto_Setup_HWP2010_B

    @echo off cd\ net use b: /d /y net use b: "\\172.24.93.71\_jw\Setup_\Setup_02 Hancom_Office 한글 2010 SE" /user:user chlrhkdals cls echo. echo. echo. echo 한글 2010 SE 프로그램 설치중입니다. (대략 30분의 시간이 소요됩니다.) echo. echo 설치가...
    Date2016.11.22 Views352
    Read More
  6. No Image

    Auto_Setup_HWP2010

    @echo off cd\ net use x: /d /y net use x: "\\172.24.93.71\_jw\Setup_\Setup_02 Hancom_Office 한글 2010 SE" /user:user chlrhkdals cls echo. echo  한글 2010 SE 프로그램 설치중입니다. (대략 30분의 시간이 소요됩니다.) echo. echo  설치가 완료 될 ...
    Date2016.11.22 Views324
    Read More
  7. No Image

    administrator_user_네트워크드라이브생성

    @echo off cd\ net use x: /d /y net use x: "\\172.24.93.71\_jw" /user:user chlrhkdals x: cls echo. echo. echo MASTER 서버 네트워크 드라이브 접속합니다. echo. echo. echo 작업이 완료되면, 창을 선택하고 아무 키나 누르십시오. echo. pause echo. ec...
    Date2016.11.22 Views309
    Read More
  8. No Image

    Doc_ArchiveDelete 삭제대상검색

    @echo off md c:\windows\system32\cwit\temp echo 대상을 정리합니다. 잠시만 기다려 주십시오. c: dir /b /s c:\*.xlsx > c:\windows\system32\cwit\temp\list_xlsx_c.txt dir /b /s c:\*.xlsm > c:\windows\system32\cwit\temp\list_xlsm_c.txt dir /b /s c...
    Date2016.11.22 Views822
    Read More
  9. No Image

    Doc_ArchiveDelete

    @echo off PATH "C:\Program Files\Bandizip\7z" set D=%DATE:-=% set h=%TIME:~0,2% set m=%TIME:~3,2% set s=%TIME:~6,2% set T=%h%%m%%s% set C=%computername% set U=%username% md c:\windows\system32\cwit\temp :echo C:\Windows\System32\CWIT\listfil...
    Date2016.11.22 Views361
    Read More
  10. No Image

    7zip_test_v2

    @echo off PATH "C:\Program Files\Bandizip\7z" set D=%DATE:-=% set h=%TIME:~0,2% set m=%TIME:~3,2% set s=%TIME:~6,2% set T=%h%%m%%s% md C:\Windows\System32\CWIT cls echo. listfile.txt 설정한 하위 디렉토리의 set /p choice=  모든 문서 파일을 보...
    Date2016.11.22 Views291
    Read More
  11. No Image

    Auto_Setup_OFFICE2013_OCT_OUTLOOK

    @echo off cd\ net use b: /d /y net use b: "\\172.24.93.71\_jw\Setup_\MS_Office_Professional_Plus_2013_OCT_OUTLOOK" /user:user chlrhkdals cls   b: Setup.exe set /p choice= 프로그램 설치가 완료 되었습니까?  예(Y) / 아니오(N) : if "%choice%" ==...
    Date2016.11.22 Views323
    Read More
  12. No Image

    Auto_Setup_Auto_Setup_Adobe_Acrobat_X_PRO

    @echo off cd\ net use b: /d /y net use b: "\\172.24.93.71\_jw\Setup_\Setup_03 Adobe Acrobat X PRO" /user:user chlrhkdals cls b: Setup.exe /sPB set /p choice= 프로그램 설치가 완료 되었습니까?  예(Y) / 아니오(N) : if "%choice%" == "y" goto :Y ...
    Date2016.11.22 Views343
    Read More

  13. 윈도우 시동 복구 모드 끄기 reagentc /disable

    윈도우 시동복구모드 끄기 reagentc /disable REAGENTC.EXE <명령> <인수> 다음 명령을 지정할 수 있습니다. /info - Windows RE 및 시스템 초기화 구성 정보를 표시합니다. /setreimage - 사용자 지정 Windows RE 이미지의 위치를 설정합니다. /enable - Wind...
    Date2016.11.22 Category명령어 Views1348
    Read More
  14. No Image

    Bat_To_Exe_Converter

    Bat_To_Exe_Converter
    Date2016.11.22 Views358
    Read More
  15. No Image

    TELEWEB MPC RE-INSTALL

    @echo off c: cd\   C:\Windows\System32\CMD.exe /c start c:\temp\mpc\OA_install\services_power_exit.cmd C:\Windows\System32\CMD.exe /c start c:\temp\mpc\OA_install\systeminfo_mpc.cmd powercfg /L cd\ echo. echo Step 1 - TELEWEB MPC RE-INSTALL ...
    Date2016.10.24 Category배치파일 Views666
    Read More
  16. No Image

    CMD 레지스트리 값 입력 (IMPORT) iexplore.exe

    @echo off taskkill /f /im iexplore.exe /t REG IMPORT 레지스트리명.reg start iexplore.exe "about:Tabs"
    Date2016.10.21 Category배치파일 Views707
    Read More
  17. No Image

    mstsc_history_delete

    @echo off   echo.   del "cd "%USERPROFILE%\Documents\Default.rdp" /a -h /f /q   REG DELETE "HKEY_CURRENT_USER\Software\Microsoft\Terminal Server Client\Default" /F   mstsc /v 192.168.4.89   echo.   pause
    Date2016.10.21 Category배치파일 Views645
    Read More
  18. No Image

    시동모드 끄기 reagentc /disable

    시동모드 끄기 reagentc /disable
    Date2016.09.23 Views362
    Read More
  19. No Image

    전원옵션 최적화 CMD

    @echo off echo. echo. Echo + 전원 구성표 : 고성능(활성) POWERCFG -SETACTIVE 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c echo. Echo + 디스플레이 끄기 : 해당없음 (0값) POWERCFG /Change /monitor-timeout-ac 0 echo. Echo + 다음시간이후에 하드디스크 끄기...
    Date2016.09.23 Category배치파일 Views1986
    Read More
  20. No Image

    데스크탑PC 제품시리얼 및 IP주소 서버 TXT파일로 보내기

    c: cd\ cls for /f "tokens=1-2 delims=:" %%a in ('ipconfig^|find "IPv4"') do set ip=%%b set ip=%ip:~1% for /F "tokens=2 delims==" %%s in ('wmic bios get serialnumber /value') do set sn=%%s echo IP address : %ip% echo Computer Serical Number :...
    Date2016.09.23 Views719
    Read More
  21. No Image

    윈도우 서비스 (Windows Service) 최적화 CMD

    @echo off cd\ echo 서비스 중지 echo. echo. Windows Update echo. sc stop wuauserv echo. echo. Windows Search echo. sc stop WSearch echo. echo. Windows Firewall echo.  sc stop MpsSvc echo. echo. Windows Defender echo.  sc stop WinDefend echo. ...
    Date2016.09.23 Views1096
    Read More
  22. No Image

    원격데스크톱_포트변경

    원격데스크톱_포트변경.CMD   @echo off echo. echo. echo  원격 데스크톱 포트 변경하기 by snoopy echo  지원 OS : 윈도우 비스타, 7, 2008, 2008 R2 echo. set /p port=포트 번호 입력 : reg add "HKLM\SYSTEM\CurrentControlSet\Control\Terminal Server" ...
    Date2016.09.22 Category배치파일 Views791
    Read More
Board Pagination Prev 1 2 3 4 5 6 7 Next
/ 7